alalCallback

アルファレイヤーのWindowsメッセージ割り込み指定

alalCallback p1,*label

(プラグイン / モジュール : a2d+AlphaLayer)

解説

アルファレイヤー子ウィンドウにウィンドウメッセージが送られたときに割り込みジャンプするラベルを指定します。

この命令を使うと、アルファレイヤー子ウィンドウにコールバックをセットしてサブクラス化することができます。

割り込みによりジャンプを行なった後はシステム変数iparam、wparam、lparamがセットされます。
割り込みが発生したArtlet2D仮想イメージIDは、 ginfo(24)またはginfo_intidにより取得することができます。

システム変数iparamには、送信されたメッセージIDが代入されます。
また、wparam,lparamはWindowsメッセージとして渡されたパラメータがそのまま格納されています。
statには割り込みが発生したArtlet2D仮想イメージIDが持つアルファレイヤー子ウィンドウのウィンドウハンドルが格納されています。

この機能を使うことで、アルファレイヤーがクリックされたりすることを検知できるようになります。

また、ラベル先ではstopをしないで、必ずreturnしてください。
waitもしてはダメです。

基本的に、コールバックで受け取ったメッセージは DefWindowProc を使ってスルーしています。
return -1 とすることで通常処理させることも可能です。(モジュール側でCallWindowProcします。)

alalSetParent の第5引数でもメッセージ割り込みラベルの指定ができます。

コールバックを解除するには、p2を省略した alalCallback を実行してください。

マウスの通過でもラベルジャンプが行われ、wait/awaitの待機時間が無効化されてしまいます。
timer_waiton/timer_awaiton を併用してください。
（mod_TimerRepeat.hsp をインクルードすればwait/awaitの機能が上書きされます。）

サンプル

#include "a2d+AlphaLayer.hsp"
#include "mod_TimerRepeat.hsp"

	// キャラ素材ロード
	alCreateImageByFile 0, dir_tv+"tamadot.png"
	
	// キャラ
	alCreateImage 1, 64,64 ; 仮想イメージ(イメージID 1)
	alalSetParent 1,,, 100,380
	alalCallback 1,*click
	mes "珠音ちゃんをクリックしてみよう！"
	
	// alCopyImageToImage と alalRedraw を繰り返す
	repeat
		alErase
		alCopyImageToImage 0,1, 0,0,64,64, 64*(4+cnt\4),0 ; 歩きモーション
		alalRedraw 1
		wait 50
		if dame>0 {
			while dame
				dame = 0
				wait 100
			wend
		}
	loop
	stop

*click
	switch iparam
		case 0x0201 ;WM_LBUTTONDOWN
			mes "痛っ！"
			dame=1
			alCopyImageToImage 0,1, 0,0,64,64, 64*1,0 ; ダメージモーション
			alalRedraw 1
		
			alalGetRect 1, rect ; アルファレイヤー(ID 1)の位置を取得
			alalWidth 1, ,, rect(0),rect(1)-20 ; アルファレイヤー(ID 1)の位置を移動
			swbreak
	swend
	return

関連項目

サンプル逆引き (3)

情報