;￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣
; ニコニコ動画のコメント取得モジュール

#module nicomment
#include "hspsock.as"

;////
;// ソケットで文字列POST
;//   Socket_HTTP_POST p1,p2,p3,p4
;//   p1      :送信するPOST文字列
;//   p2      :接続先URL
;//   P3      :送信先PATH
;//   p4=変数 :受信内容が格納される変数名
;//   
;//   戻り値 : 1=成功、0=失敗
;////

#deffunc Socket_HTTP_POST str _prm, str url, str path, var ret

  flg=0
  sdim buf,64000
  sdim temp_buf,32000

  ;POST文字列
  prm=_prm
  prm_len=strlen(prm)
  ;POST
  sockopen 0, url, 80
  sockput "POST "+path+" HTTP/1.0\nContent-type: application/x-www-form-urlencoded\n",0
  sockput "Content-length: "+prm_len+"\n\n", 0
  sockput prm, 0

;取得ループ
  repeat 1000
    ;パケット取得部分
    sockget temp_buf, 32000, 0
    if stat!0 {
      flg=0
      break
    }
    ;内容確認
    if peek(temp_buf, 0)=0 {
      ;受信終了したなら
      flg = 1
      break
    }
    buf+=temp_buf
    await 100
  loop
  ;フラグ判定
  if flg!0 {
    ;受信成功したなら
    ret=buf
  } else {
    ;受信失敗したなら
    buf=""
  }
  sockclose 0
  sdim buf,0
  sdim temp_buf,0
  return flg

;////
;// IE COM の初期化
;//   ieCOM_Init p1
;//   p1=ウィンドウID(適当な空いてるID)
;//   
;//   戻り値 : オブジェクトID、-1=失敗
;////
#deffunc ieCOM_Init int id

  sel=ginfo_sel
  screen id,1,1,3

  // ActiveXコントロール（IEコンポーネント）の配置
  axobj ieBrowser, "Shell.Explorer.2"
  idIE = stat
  if idIE == -1 {
      dialog "ActiveXコントロールの配置に失敗しました。", 1
  }
  gsel sel
  return idIE

;////
;// ニコニコ動画のコメントXMLを取得
;//   NicoNicoCommentXML_Get p1,p2,p3,p4
;//   p1=変数    :コメントXMLが代入される変数名
;//   p2         :ビデオID(sm***)
;//   p3=0～1000 :取得コメント数
;//   p4         :オプション。 0で通常コメント、1で投稿者コメントを取得する
;//   
;//   戻り値 : 1=成功、0=失敗
;////
#deffunc NicoNicoCommentXML_Get var xml, str sm, int res, int option

  ;IEコンポーネントでアクセスしてスレッドID等を取得する
  ieBrowser->"Navigate" "http://www.nicovideo.jp/api/getflv?v="+sm

  ;ウェイト
  gosub *busywait

  ;IEコンポーネントからテキストを取得
  objDoc=ieBrowser("Document")
  objBody=objDoc("body")
  ReturnHTML=objBody("innerText")
  ;//必要部分を切り取り
  i=0
  ;スレッドID取得
  j=instr(ReturnHTML,0,"thread_id=") :i+=j+strlen("thread_id=")
  getstr video_thread, ReturnHTML, i, '&' :i+=strsize
  ;APIのURL取得
  j=instr(ReturnHTML,i,"ms=http%3A%2F%2F") :i+=j+strlen("ms=http%3A%2F%2F")
  getstr _api_url, ReturnHTML, i, '&'
  ; URLエンコードされてる"/"を元に戻す
  i=0 :api_url=""
  repeat
    j=instr(_api_url, i, "%2F")
    if j=-1 {
      api_url+=strmid(_api_url, i, strlen(_api_url)-i)
      break
    }
    api_url+=strmid(_api_url, i, j)+"/" :i+=j+3
  loop

  ;POST文字列
  postmes = "<thread "
  if option=1 :postmes+= "fork=\"1\" "
  postmes+= "thread=\""+video_thread+"\" version=\"20061206\" res_from=\"-"+res+"\" />"
  ;APIのURLをドメイン名と残りに分断
  getstr jp, api_url, 0, '/'
  api=strmid(api_url,strsize-1, strlen(api_url)-strsize+1)
  ;POST
  Socket_HTTP_POST postmes, jp, api, xml
  if stat=1 {
    ;返ってきた文字列から必要部分を切り取り
    i=instr(xml, 0, "<?xml")
    xml=strmid(xml, i, strlen(xml)-i)

    ;投稿者コメントの場合、コメントが無ければ失敗扱い
    if option=1 {
      i=0
      i+=instr(xml, i, "<thread")+strlen("<thread")
      i+=instr(xml, i, ">")+1
      if strmid(xml,i,strlen("</packet>"))="</packet>" :return 0
    }
  }
  
  return

*busywait
  ;▼ページの読み込みが終了するまで待つ
  repeat
    wait 10
    if ieBrowser("Busy")==0 : break
  loop
  objDoc=ieBrowser("Document")
  repeat
    wait 10
    if (objdoc("readyState") == "complete") : break
  loop
  return

#global
;＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿


  ieCOM_Init 1

  xml=""
  sm="sm9"
  ;ニコニコ動画のコメントを取得(事前にIEでニコニコ動画へのアクセスが必要)
  NicoNicoCommentXML_Get xml, sm, 100, 0

  title ""+stat

  mesbox xml,640,480

  notesel xml
  notesave "nico.xml"